Unity3D Shader系列之圆环

Unity3D Shader系列之圆环

2020年11月14日 0 作者 老王

效果如下。
圆环效果
很简单,核心代码就下面这两句。原理就是通过计算当前uv与图片中心的距离是否在内环(_InnerRadius)和外圆(_OuterRadius)之间,若是,则将透明度置为1,若不是,则将透明度置为0。

fixed dis = distance(IN.texcoord, fixed2(0.5, 0.5));
color.a = step(_InnerRadius, dis) * step(dis, _OuterRadius);

代码中没有使用if…else…来判断,而是使用了两个step方法,这有助于提升性能。

// 这段代码没有上面使用step的方式效率高
fixed dis = distance(IN.texcoord, fixed2(0.5, 0.5));
if(dis >= _InnerRadius && dis <= _OuterRadius)
{
    color.a = 1.0;
}
else
{
    color.a = 0;
}

至于为什么step比If…else效率更高,可参考这两篇文章。
Unity Shader: 优化GPU代码–用step()代替if else等条件语句
深入GPU硬件架构及运行机制

完整代码如下。
新建个材质,材质指定该shader,然后将材质球拖拽到image上面,效果就显示出来了。

// Unity built-in shader source. Copyright (c) 2016 Unity Technologies. MIT license (see license.txt)

Shader "Custom/UI/Circle"
{
    Properties
    {
        [PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
        _Color ("Tint", Color) = (1,1,1,1)

        _OuterRadius ("Outer Radius", Range(0, 0.5)) = 0.5
        _InnerRadius ("Inner Radius", Range(0, 0.5)) = 0.2

        _StencilComp ("Stencil Comparison", Float) = 8
        _Stencil ("Stencil ID", Float) = 0
        _StencilOp ("Stencil Operation", Float) = 0
        _StencilWriteMask ("Stencil Write Mask", Float) = 255
        _StencilReadMask ("Stencil Read Mask", Float) = 255

        _ColorMask ("Color Mask", Float) = 15

        [Toggle(UNITY_UI_ALPHACLIP)] _UseUIAlphaClip ("Use Alpha Clip", Float) = 0
    }

    SubShader
    {
        Tags
        {
            "Queue"="Transparent"
            "IgnoreProjector"="True"
            "RenderType"="Transparent"
            "PreviewType"="Plane"
            "CanUseSpriteAtlas"="True"
        }

        Stencil
        {
            Ref [_Stencil]
            Comp [_StencilComp]
            Pass [_StencilOp]
            ReadMask [_StencilReadMask]
            WriteMask [_StencilWriteMask]
        }

        Cull Off
        Lighting Off
        ZWrite Off
        ZTest [unity_GUIZTestMode]
        Blend SrcAlpha OneMinusSrcAlpha
        ColorMask [_ColorMask]

        Pass
        {
            Name "Default"
        CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma target 2.0

            #include "UnityCG.cginc"
            #include "UnityUI.cginc"

            #pragma multi_compile_local _ UNITY_UI_CLIP_RECT
            #pragma multi_compile_local _ UNITY_UI_ALPHACLIP

            struct appdata_t
            {
                float4 vertex   : POSITION;
                float4 color    : COLOR;
                float2 texcoord : TEXCOORD0;
                UNITY_VERTEX_INPUT_INSTANCE_ID
            };

            struct v2f
            {
                float4 vertex   : SV_POSITION;
                fixed4 color    : COLOR;
                float2 texcoord  : TEXCOORD0;
                float4 worldPosition : TEXCOORD1;
                UNITY_VERTEX_OUTPUT_STEREO
            };

            sampler2D _MainTex;
            fixed4 _Color;
            fixed4 _TextureSampleAdd;
            float4 _ClipRect;
            float4 _MainTex_ST;

            fixed _OuterRadius;
            fixed _InnerRadius;

            v2f vert(appdata_t v)
            {
                v2f OUT;
                UNITY_SETUP_INSTANCE_ID(v);
                UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(OUT);
                OUT.worldPosition = v.vertex;
                OUT.vertex = UnityObjectToClipPos(OUT.worldPosition);

                OUT.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);

                OUT.color = v.color * _Color;
                return OUT;
            }

            fixed4 frag(v2f IN) : SV_Target
            {
                half4 color = (tex2D(_MainTex, IN.texcoord) + _TextureSampleAdd) * IN.color;

                #ifdef UNITY_UI_CLIP_RECT
                color.a *= UnityGet2DClipping(IN.worldPosition.xy, _ClipRect);
                #endif

                #ifdef UNITY_UI_ALPHACLIP
                clip (color.a - 0.001);
                #endif

                fixed dis = distance(IN.texcoord, fixed2(0.5, 0.5));
                color.a = step(_InnerRadius, dis) * step(dis, _OuterRadius);

                return color;
            }
        ENDCG
        }
    }
}